Pastebin on p.luis.im

# Maintainer: Luis Aranguren <pizzaman@hotmail.com> 

# Contributor: GreenRaccoon23 <GreenRaccoon23 AT gmail DOT com> 

# Based on PKGBUILD from vertcoin-git maintained by Lothar_m <lothar_m AT riseup DOT net> 

# WARNING: Use the `dashcore` package instead of this one unless you know what 

# you are doing. The `dashcore` package provides the official, supported, tested, 

# stable, precompiled build. This package provides the development, unstable, 

# untested, and therefore possibly broken build. Use at your own risk. 

pkgname='dashcore-git' 

_gitname='dash' 

_gitbranch='master' 

pkgver=v0.14.0.2.r0.g28a219ff0 

pkgrel=1 

arch=('x86_64') 

url="https://www.dash.org/" 

depends=('qt5-base' 'boost' 'boost-libs' 'miniupnpc' 'openssl') 

makedepends=('autoconf' 'automake' 'binutils' 'gcc' 'libtool' 'make' 'pkg-config' 'git' 'qrencode' 'protobuf' 'qt5-tools' 'python3' 'cmake') 

license=('MIT') 

pkgdesc="Dash Core (DASH, Dashpay, formerly Darkcoin) is an open source, privacy-centric digital currency. (Includes the qt-client, the headless daemon and the command-line tool). WARNING: Unstable, development version." 

provides=('dashd' 'dash-qt' 'dash-cli') 

conflicts=('dashcore') 

source=("git://github.com/dashpay/dash.git") 

sha512sums=('SKIP') 

prepare () { 

   cd "$_gitname" 

 #  git checkout "$_gitbranch" 

   git pull origin v0.14.0.x 

} 

pkgver() { 

  cd "$_gitname" 

#  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD) 

( set -o pipefail 

    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' || 

    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)" 

  ) 

} 

build() { 

  CXXFLAGS+=" -fPIC -DBOOST_VARIANT_USE_RELAXED_GET_BY_DEFAULT=1" 

  cd "$_gitname" 

  echo "=========================GIT CHECKOUT #2=================================" 

  CPPFLAGS="${CPPFLAGS} -I$PWD/depends/built/x86_64-pc-linux-gnu/include" 

  LDFLAGS="${LDFLAGS} -L${PWD}/depends/built/x86_64-pc-linux-gnu/lib -L${PWD}/depends/built/x86_64-pc-linux-gnu/lib64" 

  cd depends 

  echo "==========================START MAKE DEPENDS=============================" 

  make -j$nproc 

  cd .. 

  echo "==========================START AUTOGEN==================================" 

  ./autogen.sh 

  echo "==========================START CONFIGURE================================" 

  ./configure --prefix=`pwd`/depends/$CARCH-pc-linux-gnu --with-incompatible-bdb --with-gui=qt5 --enable-tests=no --enable-hardening 

  echo "==========================START MAKE=====================================" 

  make 

} 

package() { 

  install -D -m755 "$srcdir/$_gitname/src/qt/dash-qt" "$pkgdir/usr/bin/dash-qt" 

  install -D -m755 "$srcdir/$_gitname/src/dashd" "$pkgdir/usr/bin/dashd" 

  install -D -m755 "$srcdir/$_gitname/src/dash-cli" "$pkgdir/usr/bin/dash-cli" 

  install -D -m644 "$srcdir/$_gitname/COPYING" "$pkgdir/usr/share/licenses/$pkgname/LICENSE" 

  install -D -m644 "$srcdir/$_gitname/share/pixmaps/dash128.png" "$pkgdir/usr/share/pixmaps/dash128.png" 

  install -D -m644 "$srcdir/$_gitname/contrib/debian/dash-qt.desktop" "$pkgdir/usr/share/applications/dash-qt.desktop" 

}